B::Deparse->coderef2text does not subs with signatures

[leonerd]

Tested by running

perl -MB::Deparse -E 'say B::Deparse->new->coderef2text( sub ($x, $y) { return $x + $y } )

across various Perl versions. Up until 5.34, it yields the expected result, having a signature in the rendered output:

  --- perl5.16.3 --- 
($x,$y) {
    use feature 'current_sub', 'evalbytes', 'fc', 'say', 'state', 'switch', 'unicode_strings', 'unicode_eval';
    return $x + $y;
}

  --- perl5.18.4 --- 
($x,$y) {
    use feature 'current_sub', 'evalbytes', 'fc', 'say', 'state', 'switch', 'unicode_strings', 'unicode_eval';
    return $x + $y;
}

...

  --- perl5.34.3 --- 
($x, $y) {
    use feature 'current_sub', 'bitwise', 'evalbytes', 'fc', 'postderef_qq', 'say', 'state', 'switch', 'unicode_strings', 'unicode_eval';
    return $x + $y;
}

Thereafter, since 5.36, it no longer renders signature output, instead unpacking the code into equivalent(ish) prior behaviour:

  --- perl5.36.3 --- 
{
    do {
        use feature 'current_sub', 'bitwise', 'evalbytes', 'fc', 'isa', 'postderef_qq', 'say', 'signatures', 'state', 'unicode_strings', 'unicode_eval';
        die sprintf("Too many arguments for subroutine at %s line %d.\n", (caller)[1, 2]) unless @_ <= 2;
        die sprintf("Too few arguments for subroutine at %s line %d.\n", (caller)[1, 2]) unless @_ >= 2;
        my $x = $_[0];
        my $y = $_[1]
    };
    return $x + $y;
}

  --- perl5.38.3 --- 
{
    do {
        use feature 'current_sub', 'bitwise', 'evalbytes', 'fc', 'isa', 'module_true', 'postderef_qq', 'say', 'signatures', 'state', 'unicode_strings', 'unicode_eval';
        die sprintf("Too many arguments for subroutine at %s line %d.\n", (caller)[1, 2]) unless @_ <= 2;
        die sprintf("Too few arguments for subroutine at %s line %d.\n", (caller)[1, 2]) unless @_ >= 2;
        my $x = $_[0];
        my $y = $_[1]
    };
    return $x + $y;
}

...

  --- perl5.42.0 --- 
{
    do {
        use feature 'current_sub', 'bitwise', 'evalbytes', 'fc', 'isa', 'module_true', 'postderef_qq', 'say', 'signatures', 'state', 'try', 'unicode_strings', 'unicode_eval';
        die sprintf("Too many arguments for subroutine at %s line %d.\n", (caller)[1, 2]) unless @_ <= 2;
        die sprintf("Too few arguments for subroutine at %s line %d.\n", (caller)[1, 2]) unless @_ >= 2;
        my $x = $_[0];
        my $y = $_[1]
    };
    return $x + $y;
}

[jkeenan]

This presumably could be pinned down to a specific commit via bisection. I'd normally take that on, but will be otherwise occupied for several hours.

[leonerd]

I have done this manually. Starting with

git bisect good v5.34.0
git bisect bad v5.36.0

After bisecting this down, I find this is the breaking commit:

commit 3d1a4f06721f5fc5870542326c4cfeebe339db99
Author: Paul "LeoNerd" Evans <leonerd@leonerd.org.uk>
Date:   Tue Feb 15 18:54:29 2022 +0000

    Add 'signatures' to :5.36 feature bundle

Hoist by my own petard. Again.

3d1a4f0

[leonerd]

Hmm. Initially, I thought this might be to do with the implicit signatures feature in the use v5.36 bundle, but that doesn't appear to be the case:

$ perl5.36.2 -MB::Deparse -e 'use feature qw( say signatures ); say B::Deparse->new->coderef2text( sub ($x, $y) { $x + $y } )'
{
    do {
        use feature 'say', 'signatures';
        die sprintf("Too many arguments for subroutine at %s line %d.\n", (caller)[1, 2]) unless @_ <= 2;
        die sprintf("Too few arguments for subroutine at %s line %d.\n", (caller)[1, 2]) unless @_ >= 2;
        my $x = $_[0];
        my $y = $_[1]
    };
    $x + $y;
}

$ perl5.36.2 -MB::Deparse -e 'use v5.36; say B::Deparse->new->coderef2text( sub ($x, $y) { $x + $y } )'
{
    do {
        use warnings;
        use strict;
        no feature ':all';
        use feature ':5.36';
        die sprintf("Too many arguments for subroutine at %s line %d.\n", (caller)[1, 2]) unless @_ <= 2;
        die sprintf("Too few arguments for subroutine at %s line %d.\n", (caller)[1, 2]) unless @_ >= 2;
        my $x = $_[0];
        my $y = $_[1]
    };
    $x + $y;
}

Both bundle and explicit feature are broken.

I think this may be related to the feature_enabled method in B/Deparse.pm, around here:

https://github.com/Perl/perl5/blob/v5.36.0/lib/B/Deparse.pm#L2346

Some warn-based testing suggests that on earlier Perls it's fine, but on 5.36 onwards it no longer believes the "signatures" feature is ever enabled.

[leonerd]

Ugh. My original summary is wrong here. This has never ever worked.

The (not so) subtle clue is that on first glance above, it appeared to work even at Perl version 5.16 - notable for the fact that signatures weren't even a thing until 5.20 ;)

Turns out, before 5.36, that leading text is taken as a prototype and, without warnings turned on, perl remains silent about its odd shape and just emits it as verbatim text.

It turns out that B::Deparse never ever emits signatures when calling ->coderef2text on a signatured sub.

$ eachperl -MB::Deparse -Mfeature=say,signatures -e 'say B::Deparse->new->coderef2text( sub ($x, $y) { return $x + $y } )' 
  --- perl5.14.4 --- 
Feature "signatures" is not supported by Perl 5.14.4 at -e line 0.
BEGIN failed--compilation aborted.

  --- perl5.16.3 --- 
Feature "signatures" is not supported by Perl 5.16.3 at -e line 0.
BEGIN failed--compilation aborted.

  --- perl5.18.4 --- 
Feature "signatures" is not supported by Perl 5.18.4 at -e line 0.
BEGIN failed--compilation aborted.

  --- perl5.20.3 --- 
The signatures feature is experimental at -e line 1.
{
    use feature 'say', 'signatures';
    die 'Too many arguments for subroutine' unless @_ <= 2;
    die 'Too few arguments for subroutine' unless @_ >= 2;
    my $x = $_[0];
    my $y = $_[1];
    ();
    return $x + $y;
}

...

  --- perl5.42.0 --- 
{
    do {
        use feature 'say', 'signatures';
        die sprintf("Too many arguments for subroutine at %s line %d.\n", (caller)[1, 2]) unless @_ <= 2;
        die sprintf("Too few arguments for subroutine at %s line %d.\n", (caller)[1, 2]) unless @_ >= 2;
        my $x = $_[0];
        my $y = $_[1]
    };
    return $x + $y;
}

[leonerd]

OKaaaaay. All of this is a huge misunderstanding on my part.

->coderef2text is supposed to emit signatures, or not, based on whether the ambient context (as provided by ambient_pragmas) as the signatures feature enabled. If you never set that from the caller, then it won't ever be set.

Currently it seems you have to do a rather longwinded copypasted piece of code, looking something like

my ($hints, $warnings, $hinthash);
BEGIN {
  $hints = $^H;
  $warnings = ${^WARNING_BITS};
  $hinthash = \%^H;
}
$deparser->ambient_pragmas(
  hint_bits => $hints,
  warning_bits => $warnings,
  '%^H' => $hinthash,
);

whereupon it will magically start to do what you expect.

I think therefore this issue becomes two things:

1. Better support (or at least documentation) on how to do that common step a LOT easier. I suspect adding a ->ambient_pragmas_from_caller method would be useful, as it can grab all the relevant information from (caller)[8,9,10]
2. Add some tests into lib/B/Deparse.t that demonstrate it is working, and to act as a suitable hint for users to know how to do it.

In addition, there's currently actually a bug, in that on 5.43.x it emits

unexpected OP_MULTIPARAM at lib/B/Deparse.pm line 1786, <DATA> chunk 304.

So some work still needed here.

[leonerd]

I have made some effort to address this:

#23710